1 files changed, 37 insertions, 0 deletions
diff --git a/tools/minimap2-align.nix b/tools/minimap2-align.nix
new file mode 100644
index 0000000..14c88a5
--- /dev/null
+++ b/tools/minimap2-align.nix
@@ -0,0 +1,37 @@
+{ bionix
+, ref
+, bamOutput ? true
+, flags ? null
+, preset
+}:
+
+{ input1
+, input2 ? null
+}:
+
+with bionix;
+with lib;
+with types;
+with compression;
+
+let
+  fa = f: matchFiletype "minmap2-ref" { fa = _: f; } f;
+  fq = f: matchFiletype "minmap2-input" { fq = _: f; gz = matchFiletype' "minmap2-input" { fq = _: f; }; } f;
+
+in stage {
+  name = "minmap2-align";
+  buildInputs = with pkgs; [ minimap2 bc ] ++ optional bamOutput samtools;
+  buildCommand = ''
+    ln -s ${fa ref} ref.fa
+    cores=$(echo $NIX_BUILD_CORES ${optionalString bamOutput "- 1"} | bc)
+    if [[ $cores -lt 1 ]] ; then
+      cores=1
+    fi
+    minimap2 ${optionalString (flags != null) flags} -t $cores -ax ${preset} ref.fa ${fq input1} \
+      ${optionalString (input2 != null) (fq input2)} \
+      ${optionalString bamOutput "| samtools view -b"} \
+      > $out
+  '';
+  passthru.filetype = if bamOutput then filetype.bam {ref = ref; sorting = sort.name {};} else filetype.sam {ref = ref; sorting = sort.name {};};
+  passthru.multicore = true;
+}